+Show TOC
×Hide TOC

EventDispatcher

Kind of class:	class
Inherits from:	CoreObject
Implements:	DispatchableInterface
Known subclasses:	Chain DistributionCollection EnterFrame EventKey EventMouse EventStage Inactivity Load LoadGroup LoadManager Timer Tween
Version:	07/12/07
Author:	Aaron Clinger, Mike Creighton
Classpath:	org.casalib.event.EventDispatcher
File last modified:	Monday, 01 December 2008, 13:34:40

► View source

▼ Hide source

/*
    CASA Lib for ActionScript 2.0
    Copyright (c) 2008, Aaron Clinger & Contributors of CASA Lib
    All rights reserved.
    
    Redistribution and use in source and binary forms, with or without
    modification, are permitted provided that the following conditions are met:
    
    - Redistributions of source code must retain the above copyright notice,
      this list of conditions and the following disclaimer.
    
    - Redistributions in binary form must reproduce the above copyright notice,
      this list of conditions and the following disclaimer in the documentation
      and/or other materials provided with the distribution.
    
    - Neither the name of the CASA Lib nor the names of its contributors
      may be used to endorse or promote products derived from this software
      without specific prior written permission.
    
    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
    AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
    IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
    ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR CONTRIBUTORS BE
    LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
    CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
    SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
    INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
    CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
    ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
    POSSIBILITY OF SUCH DAMAGE.
*/

import org.casalib.core.CoreObject;
import org.casalib.event.DispatchableInterface;
import org.casalib.util.TypeUtil;

/**
    Provides event notification and listener management capabilities to objects. 
    
    Advantages of using this EventDispatcher:
    <ul>
        <li>Ability to {@link #addEventObserver remap event handlers} to a function not sharing the same name as the event.</li>
        <li>Ability to {@link #removeEventObserversForEvent remove all} event observers for a specified event.</li>
        <li>Ability to {@link #removeEventObserversForScope remove all} event observers for a specified scope.</li>
        <li>Ability to {@link #removeAllEventObservers remove all} event observers subscribed to broadcasting object.</li>
    </ul>

    @author Aaron Clinger
    @author Mike Creighton
    @version 07/12/07
*/

class org.casalib.event.EventDispatcher extends CoreObject implements DispatchableInterface {
    private var $eventMap:Object;
    
    public function EventDispatcher() {
        super();
        
        this.removeAllEventObservers();
        
        this.$setClassDescription('org.casalib.event.EventDispatcher');
    }
    
    /**
        {@inheritDoc}
        
        @param scope: {@inheritDoc}
        @param eventName: {@inheritDoc}
        @param eventHandler: {@inheritDoc}
        @return {@inheritDoc}
        @example <code>this.eventButton_mc.addEventObserver(this, "onRollOver");</code>
    */
    public function addEventObserver(scope:Object, eventName:String, eventHandler:String):Boolean {
        var eventFunction:String = (eventHandler == undefined) ? eventName : eventHandler;
        
        if (!TypeUtil.isTypeOf(scope[eventFunction], 'function'))
            return false;
        
        var observers:Array = this.$eventMap[eventName];
        
        if (observers == undefined)
            observers = this.$eventMap[eventName] = new Array();
        else {
            var len:Number = observers.length;
            while (len--)
                if (observers[len].scope == scope && observers[len].funct == eventFunction)
                    return false;
        }
        
        var observer:Object = new Object();
        observer.scope      = scope;
        observer.funct      = eventFunction;
        
        observers.push(observer);
        
        return true;
    }
    
    /**
        {@inheritDoc}
        
        @param scope: {@inheritDoc}
        @param eventName: {@inheritDoc}
        @param eventHandler: {@inheritDoc}
        @return {@inheritDoc}
        @example <code>this.eventButton_mc.removeEventObserver(this, "onRollOver");</code>
    */
    public function removeEventObserver(scope:Object, eventName:String, eventHandler:String):Boolean {
        var funct:String    = (eventHandler == undefined) ? eventName : eventHandler;
        var observers:Array = this.$eventMap[eventName];
        var len:Number      = observers.length;
        
        while (len--) {
            if (observers[len].scope == scope && observers[len].funct == funct) {
                observers.splice(len, 1, null);
                return true;
            }
        }
        
        return false;
    }
    
    /**
        {@inheritDoc}
        
        @param eventName: {@inheritDoc}
        @return {@inheritDoc}
        @example <code>this.eventButton_mc.removeEventObserversForEvent("onRollOver");</code>
    */
    public function removeEventObserversForEvent(eventName:String):Boolean {
        if (this.$eventMap[eventName] == undefined)
            return false;
        
        delete this.$eventMap[eventName];
        
        return true;
    }
    
    /**
        {@inheritDoc}
        
        @param scope: {@inheritDoc}
        @return {@inheritDoc}
        @example <code>this.eventButton_mc.removeEventObserversForScope(this);</code>
    */
    public function removeEventObserversForScope(scope:Object):Boolean {
        var removed:Boolean = false;
        var observers:Array;
        var len:Number;
        
        for (var i:String in this.$eventMap) {
            observers = this.$eventMap[i];
            len       = observers.length;
            
            while (len--) {
                if (observers[len].scope == scope) {
                    observers.splice(len, 1, null);
                    removed = true;
                }
            }
        }
        
        return removed;
    }
    
    public function removeAllEventObservers():Boolean {
        this.$eventMap = new Object();
        
        return true;
    }
    
    /**
        {@inheritDoc}
        
        @param eventName: {@inheritDoc}
        @param param(s): {@inheritDoc}
        @return {@inheritDoc}
        @example <code>this.dispatchEvent("onRelease", 5, true, "Aaron");</code>
    */
    public function dispatchEvent(eventName:String):Boolean {
        var observers:Array = this.$eventMap[eventName];
        if (observers == undefined)
            return false;
        
        var i:Number              = -1;
        var originalLength:Number = observers.length;
        var dispatched:Boolean    = false;
        var observer:Object;
        
        while (++i < originalLength) {
            observer = observers[i];
            
            if (observer == null) {
                observers.splice(i, 1);
                
                if (observers.length == 0) {
                    delete this.$eventMap[eventName];
                    break;
                }
                
                i--;
                originalLength--;
            } else {
                observer.scope[observer.funct].apply(observer.scope, arguments.slice(1));
                dispatched = true;
            }
        }
        
        return dispatched;
    }
    
    public function destroy():Void {
        delete this.$eventMap;
        
        super.destroy();
    }
}

Provides event notification and listener management capabilities to objects.

Advantages of using this EventDispatcher:

Ability to remap event handlers to a function not sharing the same name as the event.
Ability to remove all event observers for a specified event.
Ability to remove all event observers for a specified scope.
Ability to remove all event observers subscribed to broadcasting object.

Summary

Constructor

EventDispatcher

Instance methods

addEventObserver (scope:Object, eventName:String, eventHandler:String) : Boolean
- Registers a function to receive notification when a event handler is invoked.
removeEventObserver (scope:Object, eventName:String, eventHandler:String) : Boolean
- Removes specific observer for event.
removeEventObserversForEvent (eventName:String) : Boolean
- Removes all observers for a specified event.
removeEventObserversForScope (scope:Object) : Boolean
- Removes all observers in a specified scope.
removeAllEventObservers : Boolean
- Removes all observers regardless of scope or event.
dispatchEvent (eventName:String) : Boolean
- Reports event to all subscribed objects.
destroy : Void
- Removes any internal variables, intervals, enter frames, internal MovieClips and event observers to allow the object to be garbage collected.

Instance methods inherited from CoreObject

$setClassDescription destroy toString

Constructor

EventDispatcher

function EventDispatcher (

)

Instance methods

addEventObserver

function addEventObserver (

scope:Object, eventName:String, eventHandler:String) : Boolean

Registers a function to receive notification when a event handler is invoked.

Parameters:

scope :

The target or object in which to subscribe.

eventName :

Event name to subscribe to.

eventHandler:

[optional] Name of function to recieve the event. If undefined class assumes this.eventButton_mc.removeEventObserversForEvent("onRollOver"); matches this.eventButton_mc.removeEventObserversForScope(this);.

Returns:

Returns this.dispatchEvent("onRelease", 5, true, "Aaron"); if the observer was established successfully; otherwise {VISDOC_CODE_BLOCK_5}.
#

Example:

this.eventButton_mc.addEventObserver(this, "onRollOver");

Specified by:

DispatchableInterface.addEventObserver

destroy

function destroy (

) : Void

Removes any internal variables, intervals, enter frames, internal MovieClips and event observers to allow the object to be garbage collected.

Always call this.eventButton_mc.addEventObserver(this, "onRollOver"); before deleting last object pointer.

Overrides:

org.casalib.core.CoreObject.destroy

Specified by:

org.casalib.core.CoreInterface.destroy

dispatchEvent

function dispatchEvent (

eventName:String) : Boolean

Reports event to all subscribed objects.

Parameters:

eventName:

Event name.

param(s) :

[optional] Parameters passed to the function specified by "eventName". Multiple parameters are allowed and should be separated by commas: param1,param2, ...,paramN

Returns:

Returns this.eventButton_mc.addEventObserver(this, "onRollOver"); if observer(s) listening to specifed event were found; otherwise this.eventButton_mc.removeEventObserver(this, "onRollOver");.
#

Example:

this.dispatchEvent("onRelease", 5, true, "Aaron");

Specified by:

DispatchableInterface.dispatchEvent

removeAllEventObservers

function removeAllEventObservers (

) : Boolean

Removes all observers regardless of scope or event.

Returns:

Returns {VISDOC_CODE_BLOCK_16} if observers were successfully removed; otherwise {VISDOC_CODE_BLOCK_17}.
#

Specified by:

DispatchableInterface.removeAllEventObservers

removeEventObserver

function removeEventObserver (

scope:Object, eventName:String, eventHandler:String) : Boolean

Removes specific observer for event.

Parameters:

scope :

The target or object in which subscribed.

eventName :

Event name to unsubscribe to.

eventHandler:

[optional] Name of function that recieved the event. If undefined class assumes {VISDOC_CODE_BLOCK_6} matched {VISDOC_CODE_BLOCK_7}.

Returns:

Returns {VISDOC_CODE_BLOCK_8} if the observer was successfully found and removed; otherwise {VISDOC_CODE_BLOCK_9}.
#

Example:

this.eventButton_mc.removeEventObserver(this, "onRollOver");

Specified by:

DispatchableInterface.removeEventObserver

removeEventObserversForEvent

function removeEventObserversForEvent (

eventName:String) : Boolean

Removes all observers for a specified event.

Parameters:

eventName:

Event name to unsubscribe to.

Returns:

Returns {VISDOC_CODE_BLOCK_10} if observers were successfully found for specified {VISDOC_CODE_BLOCK_11} and removed; otherwise {VISDOC_CODE_BLOCK_12}.
#

Example:

this.eventButton_mc.removeEventObserversForEvent("onRollOver");

Specified by:

DispatchableInterface.removeEventObserversForEvent

removeEventObserversForScope

function removeEventObserversForScope (

scope:Object) : Boolean

Removes all observers in a specified scope.

Parameters:

scope:

The target or object in which to unsubscribe.

Returns:

Returns {VISDOC_CODE_BLOCK_13} if observers were successfully found in {VISDOC_CODE_BLOCK_14} and removed; otherwise {VISDOC_CODE_BLOCK_15}.
#

Example:

this.eventButton_mc.removeEventObserversForScope(this);

Specified by:

DispatchableInterface.removeEventObserversForScope